A Noob In World of Warcraft

Macro

WoWにはMacroというシステムがあります。自分で自由に作れるのですが、自由すぎて使いこなすのが中々大変です。上手く使うと一つのボタンで2つの魔法を使い分けたり、状況に応じて使う魔法が変わるようにできたりします。

これを上手く使うと、戦闘がグッと楽になります。各classで有効なMacroがWoWWikiにあるので見てみてください。

『Macroの作り方を知りたい!』という人は、英語Wikiにあった2.0 patchのMacroガイドを管理人がフィーリング翻訳したものをどうぞ。(原文はこちら。)

2.0 Macro guide

1; Basic Macro

1.1 Macroって何?
Macroは/コマンドのリストです。Macroではこれらのコマンドをアクションボタンから一度に使う事ができます。例えば、
/y Everybody dance now!
/dance

これを実行すると『Everybody dance now!』とyellしてdanceを始めます。

1.2 Macroはどうやって作るの?
まずはEscキーでMain menuを出し、macor windowを開きます。または『/macro』を実行しても開きます。ここにGeneral MacrosとYourname Specific Macrosの2種類のTabがあるのが分かると思います。Generalは同一アカウント内キャラクター共通のMacroで、Yournameはそのキャラクター専用のMacroです。使い分けは自由にできます。

新しいMacroを作るにはまず、『New』のボタンを押します。開いたウィンドウに適当なMacroのタイトルをつけ、好きなIconを選び、OKします。後は左下の本文入力部分にMacroを書き込むだけです。タイトルやIconを変更したい時は『Change Name/ Icon』ボタンから変更できます。作ったMacroをaction barにドラッグして使用します。

1.3 どうやってspellを詠唱するの?

1.3.1
/cast はMacroで一番良く見かけるコマンドで、自分のspell bookにあるspellを詠唱するコマンドです。一番単純なものは
/cast Shadow Word: Pain
このMacroは一番ランクの高いShadow Word: Painの魔法をターゲットに使用します。
『なんでわざわざMarcoを作るの?spell boookから直接action barに放り込めば良いんじゃない?』
なぜ作るのかというと、とても便利だからです。例えば、CCに使われるMageのPolymorph (Sheep)を知っていますか?このspellを詠唱してparty memberにそれを知らせるMacroを作ります。
/cast Polymorph
/p Sheeping %t! You spank it, you tank it!

cooldownがあるspell等で詠唱できない場合があるコマンドを使用する時、/castコマンドを使用した時のみpartyメッセージを出すには/aftercastを使用します。
/aftercast /p Click the portal to get %t's lazy butt over here
/cast Ritual of Summonning

これでRitual of Summonningを詠唱できた時にpartyメッセージが出ます。

1.3.2spell名とランクについて
spellのランクを指定して唱えたい場合は
/cast Shadow Word: Pain(Rank 5)
これでRank 5のShadow Word: Painが詠唱されます。(Rank 5)の部分を消去し、Rank指定をしなければ最上位のRankが自動的に使用されます。しかし、次のような場合
/cast Farie Fire (Feral)(Rank 2)
これはFarie Fire (Feral)のRank 2を詠唱するMacroですが、ここで(Rank 2)を消去すると(Feral)の部分がRank指定と判定され、Macro Errorで詠唱されません。その場合は、
/cast Farie Fire (Feral)()
と、Rankを空欄にする事で最上位のspellが詠唱されます。

1.4 どうやってitemやtrinketを使用するの?
簡単に回答すると、spellと同じ様にします。/castの様に/useのコマンドを使用して使用したいitemの名前を指定します。
/use Green Mechanostrider
他の形式でも/useコマンドは使用できます。

1.4.1 /use <inventory slot>
装備の中にはtrinketの様に使用することで性能が発揮されるものもあります。勿論item名でも使用できますが、各装備slotには番号が割り当てられており、それを使用できます。(WoWWikiに一覧があります。
/use 13
これで上のtrinket slotに装備しているitemが使用されます。

1.4.2 /use <bag> <slot>
鞄の特定のslotに入ったitemを指定して使用することもできます。鞄はicon左から0-4の数字が割り当てられています。鞄の中は
1234
5678
9...
という風に番号が割り当てられています。
/cast Feed Pet
/use 0 1

とすると、0番の鞄の一番左上にあるitemを使用してFeed Petを実行するというMacroになります。

1.5 Multiple actions with one click
多くのspellといくつかのitemの使用はglobal cooldown (GCD)の引き金になります。GCDの間はitemの使用やspellの詠唱ができなくなります。このため次のような/castを羅列したMacroは動きません。
/cast Overpower
/cast Excute
/cast Mortal Strike
/cast Sunder Armor

しかし、instant castでGCDの引き金にならないspellの場合は動作します。(GCDの有無はthottbot等のデータベースサイトで確認できます。)そのため、以下のようなMacroは動作します。
/use Talisman of Ephemeral Power
/cast Arcane Power
/cast Presence of Mind
/cast Pyroblast

1.6 ターゲットをする
Macroにおいてターゲットも頻繁に使用されるものの一つです。/コマンドで実際にターゲットを変える方法と、optionでターゲットを設定し実際のターゲットは変わらない方法があります。opitionについては後で詳しく説明するので、ここではターゲットに限って説明をします。
もっとも単純なターゲットコマンドは/targetです。使い方も簡単で、
/target Cogwheel
近くにCogというものが無い場合は一番近いものをターゲットします。意味の無いもの(死体等)もターゲットすることがあるのでこの機能は良し悪しです。
/target Blackwing Mage
/cast Curse of Agony

これは近くにBlackwing Mageがいない場合、BとLがつく名前の見方をターゲットする場合がありますが、その場合も味方にはCurseはかからず安全です。しかし、100yard後方の敵をターゲットする事があります。(これは2.3 patchの/targetexactコマンドで解決されました)
名前の変わりにUnit IDを使うことができます。自分はplayerで現在のターゲットはtarget、ペットはpetになります。Unit IDの一覧はこちらを参考に。

1.6.1 他のターゲットコマンド

1.6.1.1 /assist
これはターゲットのターゲットしているもの(target's target)をターゲットするコマンドです。Interface optionで相手が敵の場合自動的に攻撃を開始する設定があります。

1.6.1.2 /cleartarget
現在のターゲットをclearする(何もターゲットしていない状態にする)コマンドです。

1.6.1.3 /targetlasttarget, /targetlastfriend, /targetlastenemy
それぞれ、直前のターゲットをターゲットするコマンド、直前にターゲットした味方をターゲットするコマンド、直前にターゲットした敵をターゲットするコマンドです。前にターゲットしたものが無い場合何も起こりません。

1.6.1.4 /targetenemy, /targetfriend
これはTABキーを押した時のように、近くの敵または味方を順番にターゲットしていくコマンドです。

1.6.1.5 /targetparty, /targetraid
近くにいるparty memberまたはraid memberを順番にターゲットしていくコマンドです。

1.7 ペットの行動を管理するにはどうするの?
petのability名をcastするコマンドでpetにabilityを使用させることが可能です。また、petに関するコマンドも追加されました。

1.7.1 /petattack
petが主人のターゲットを攻撃します。名前やunit IDを使ってターゲットを指定することもできます。

1.7.2 /petfollow
攻撃中でも攻撃を中止して主人の方に戻ってきます。

1.7.3 /petpassive, /petdefensive, /petaggressive
petのmodeを指定できます。(passive=こちらから指示を出すまで何もしない状態、defensive=自分または主人が攻撃されたら反撃する状態、aggressive=近くにいる敵を手当たり次第に攻撃する状態)

1.7.4 /petautocaston, /petautocastoff
spellをオートキャストさせる、またはオートキャストをさせないようにするコマンドです。例えば
/petautocaston Torment
/petautocastoff Suffering

これでTormentはオートキャストで使いSufferingはオートキャストしないように命令できます。

1.8 #showで?マークのiconに表示するものを設定する
WoWでは?マークのiconを使用した場合、Macroの一番上のspellまたはitemのiconが表示されるようになっています。
/use Talisman of Ephemeral Power
/cast Arcane Power
/stopcasting
/cast Presence of Mind
/stopcasting
/cast Pyroblast

先ほど出したMacorの例ですが、この場合はTalisman of Ephemeral Powerのiconが表示されるということです。しかし、iconはPyroblastのものを表示したい時にはMacroの1行目に
#show Pyroblast
と付け加えることで、表示されるiconを指定できます。spellだけでなく、item、item id、inventory slot、bug solot numberも使えます。
#showと同じ様に#showtooltipも使用します。action barのmacroをmouse overした時に表示されるtooltipの名前を指定します。

1.9 その他の/コマンド

1.9.1 itemを装備する
2つのコマンドがあります。/equipは単純にitem名を指定して装備するコマンドです。これは鞄の中のitemを右クリックして装備する時のようにデフォルトのslotに自動で装備されます。
/equip Honed Voidax
/equipslotはinventory slot IDを指定してitemを装備します。
/equipslot 14 Carrot on a Stick

1.9.2 spellとitemを連続させる
一つのMacroにGCDのあるspellやitemは共存できないと上で説明しましたが、GCDのあるものでも一つのMacroにする方法があります。それが/castsequenceコマンドです。これはspellやitemを順番にリストにしたようなもので、このMacroのボタンを押すたびにリストの上から順にspellやitemが実行され、成功すると次へ次へと進んでいきます。(1回1回ボタンを押さないとリストの先に進みません)例えば、
/castsequence Immolate, Corruption, Curse of Agony, Siphon Life
例えば途中で何らかの理由でCorruptionがcastされなかった場合は次に進まず、次にボタンを押した時もCorruptionが詠唱されます。spellのリストの前に、シークエンスをリセットする条件を設定することができます。
reset=n/target/combat/shift/alt/ctrl
nはシークエンスが実行されない時間がどのぐらいになったらrestするかをsecondで設定できます。targetはtargetが変わった時にresetされます。shift/alt/ctrlはこれらのキーをおしてMacroを押した時にresetする設定です。
/castsequence reset=10/shift Spell 1, Other Spell, Some Item
この場合10秒間Macro操作が無い場合とshiftボタンを押してMacroを実行した時にシークエンスがresetされ、次回実行時はSpell 1に戻ります。
iconに?マークを使用した場合、現在のシークエンスの要素のiconが表示されます。

1.9.3 spellやitemのランダムな使用
/castrandomはspell/ itemをリストにして並べ、その中からランダムに使用するコマンドです。mount使用時等に使われています。
/castrandom Swift Green Mechanostrider, Black Battlestrider, Summon Dreadsteed

1.9.4 攻撃
攻撃を開始する時は/startattackで中止する時は/stopattackを使用します。ターゲットには名前やunit IDも勿論使用できます。

1.9.5 action barの操作
action barのページを変えるコマンドは/changeactionbarです。例)
/cast Aspect of the Hawk
/changeactionbar 1

/swapactionbarコマンドは2つのページを指定し、それらを切り替えるコマンドです。例)
/swapactionbar 1 2

1.9.6 Buffを解除する
buffを解除するコマンドは/cancelauraです。例)
/cancelaura Blessing of Salvation

1.9.7 formを解除する
/cancelformはWarrior以外のstanceがあるクラス(Druidの変身やPriestのShadowform等)がformを解除するコマンドです。例)
/cancelform
/use Super Healing Potion

1.9.8 詠唱を中止する
/stopcastingは現在の詠唱を中断するコマンドです。(2.3前は詠唱のLatencyによる延長分を短縮するため多用されていましたが、現在は使いたいspellを連打するだけで延長分は自動でcutされる仕様に変更されました。)例)
/stopcasting
/cast Shadowburn

1.9.9 Macroを中断する
/stopmacroは実行中のMacroを中断するコマンドです。

1.9.10 mountを降りる
/dismountはmountを降りるコマンドです。

1.9.11 Saving a target for later action
/focusはターゲットを一つsaveしておけるコマンドです。(unitframe用のaddonを使うとfocusしている対象も表示できます。)CCの対象等に使用されます。例)
/target focus
/cast Polymorph
/targetlasttarget

Focusの使い方はまた後で解説します。

1.9.12 Simulating button clicks
/clickはボタンをクリックしたのと同じような動作をするコマンドです。ボタンの名前を確認するにはいくつか方法があります。
・いくつかのaddon (MoveAnythingのような)はマウスオーバーしたボタンの名前を表示します
・frameのUI codeを見ることで確認できますが、これは実際はaddonをプログラムする人向けです
・以下のマウスオーバーしながら以下のMacroを実行するとボタンの名前が表示されます
/run local f = GetMouseFocus(); if f then DEFAULT_CHAT_FRAME:AddMessage(f:GetName()) end
デフォルトでは左クリックですが、右クリックの設定も可能です。
/click PetActionButton5 RightButton
ボタンの設定はLeftButton, RightButton, MiddleButton, Button4, Button5があります。

1.10 scriptについて

1.10.1 scriptでできないことって何?
scriptは強力なツールですが、その力ゆえにBlizzardは機能を制限しました。現在spellを詠唱する、itemを使用する、action bar pageを変更する、ターゲットに影響する動作等に関係するscriptは使用できません。現在使用できるのは限られた極一部です。

1.10.2 じゃあscriptって何?
WoWのUIはLua script languageで書かれています。/runコマンドを使ってこのscriptシステムを使用することができます。以降LuaのプログラムとAddonの話の部分はMacroと関係ないので割愛。要はscriptをよく知りたければLearnToProgram を読めという事のようです。)
次に上げるMacroは、raid内に自分と同じターゲットの人間がいた場合ターゲットを変えるようにwhisperし、sheepを壊さないようにします。
/cast Polymorph
/run for i=1,GetNumRaidMembers()-1 do local u,t="raid"..i,"target"if UnitIsUnit(u..t,t)then SendChatMessage("Change targets! Trying to sheep...","WHISPER",nil,UnitName(u))end end

2 Macro Options

2.1 macro optionて何?
macro optionはmacroの動作をコントロールする方法です。次の例は味方にはRenewを詠唱し、敵にはShadow Word: Painを詠唱するmacroです。
/cast [help] Renew; [harm] Shadow Word: Pain
helpは味方、harmは敵の意味です。ターゲットがhelpだった場合Renewが詠唱されますが、条件がfail(ターゲットが味方ではなかった)の場合次の条件に進み、ターゲットがharmの場合Shadow Word: Painが詠唱されますが、それもfailの場合は何も起こりません。

2.2 optionが使えるコマンド
以下のコマンドにはoptionが使えます。
#show
#showtooltip
/assist
/cancelaura
/cancelform
/cast
/castrandom
/castsequence
/changeactionbar
/clearfocus
/cleartarget
/click
/dismount
/equip
/equipslot
/focus
/petagressive
/petattack
/petautocastoff
/petautocaston
/petdefensive
/petfollow
/petpassive
/petstay
/startattack
/stopattack
/stopcasting
/stopmacro
/swapactionbar
/target
/targetenemy
/targetfriend
/targetlasttarget
/targetparty
/targetraid
/use
/userandom

2.3 [target=unit]
条件のチェックに加え、optionで様々な動作のターゲットを設定することができます。例えば、以下のmacroでは現在のターゲットに関わらず自分にbandageを使用します。
/use [target=player] Heavy Netherweave Bandage
動作のターゲットを設定するだけでなく、[target=]自体も条件のチェックができます。
/cast [help] [target=targettarget, help] [target=player] Flash Heal
まずターゲットがhelpかどうかをチェックし、true(ターゲットが味方)ならFlash Healを詠唱します。違う場合は次の条件に行きます。targetのtargetが味方ならばtargetのtargetにFlash Healを詠唱します。それもまたfailならば自分にFlash Healを詠唱します。

2.4 構文の概要
どのようにmacro optionが動くのか、実際の例を上げて解説していきます。

2.4.1 一般的なoptionの構文
/コマンドは基本的に同じように動作します。一つのコマンドと1セットのパラメーターがあり、パラメーターはコマンドに依存し、いくつかのコマンドはパラメーターを要しません。例を上げます。
/cast Smite
は/castがコマンドでSmiteがパラメーターです。
/petattack
は/petattackがコマンドでパラメーターは空欄です。
/castsequence reset=target Immolate, Corruption, Curse of Agony, Siphon Life
は/castsequenceがコマンドでresetからSiphon Lifeまでがパラメーターです。
macro opitonは一つの基準に基づいて一つのパラメーターを選択できる。高度になるとセミコロンで区切ったパラメーターのグループにもできます。それぞれの条件は[]で区切られます。
/command [条件] [別の条件] parameters; [条件] parameters...
コマンドは左から右へ条件がチェックされていき、trueの条件があった所ですぐに実行されます。条件がない場合は常にtrueです。trueの条件がない場合macroは実行されません。

2.4.2 条件構文
条件のセットは『,』で区切ります。[target=]は常に最初に考慮されます。[help, nodead, target=focus]は『Focusしている対象が味方で死んでいない場合』という意味になります。
nodeadのnoは反対の条件を意味します。nohelpはharmと同じ様な意味です。しかし、中にはhelpでもharmでもないターゲットも存在します。(pvpフラグを立てていない敵エリアの敵PCやnon-combatのペット、エスコートクエスト等)
条件の中には独自のパラメーターを持つものがあります。例えば[stance]です。パラメーターの開始は『:』で、それぞれのパラメーターは『/』で区切られます。次の例はWarrがDefensiviまたはBattle Stanceの時にはShield BashをBerserker Stanceの時にはDefensive Stanceに変更するMacroです。
/cast [stance:1/2] Shield Bash; Defensive Stance

2.4.3 完全版EBNF構文
コマンド=/command-verb [object; object]
command-verb=optionで使えるコマンド参照
object=条件 パラメーター
パラメーター=コマンドに繋がる何か
条件=[condition-phrase, condition-phrase]
condition-phrase=[no], option-word, [:option-argument/option-argument]
option-argument=shiftやctrl、target、1、2等のoption

2.4.4 空欄のパラメーター
パラメーターが空欄の時の扱いに混乱の元があります。よくあるerrorは、macro記述中に余計なセミコロンを最後につけてしまうことですが、これは思いがけないbugを起こします。
/petattack [target=focus, harm];
これはFocusしている相手が敵の場合petに攻撃させ、その他の事は起こらないように見えます。しかし、次のMacroを見て下さい。
/petattack [target=focus, harm] ;
optionの後に空欄があり、セミコロンの後に空欄のパラメーターがあると認識されます。空欄のパラメーターは常にtrueです。つまり、最初の条件がfaleseの場合次の空欄のパラメーターがtrueと評価され、petattackが実行されます。

2.4.5 Empty conditions
ある特定の状態にあるターゲットにコマンドを実行したいが、その状態に無い時は通常にコマンドを実行したい時があります。この場合は常にtrueで評価される空欄の条件を使います。次のmacroはマウスオーバーした相手が味方に場合にFlash of Lightを詠唱し、敵の場合は現在のターゲットまたはInterface optionでself-castを設定してる場合はself-cast kyeにより自分にFlash of Lightを詠唱できます。
/cast [target=mouseover, help] [] Flash of Light

2.4.6 [target=] vs. unit parameters
いくつかのコマンドはユニットをパラメーターとして使用できます。例えば/target party1は一番上のparty memberをターゲットします。/target [target=party1]も動作します。しかし、ほとんどの場合、一つのユニットの条件を調べ別のユニットに動作させるということはできません。
/target [target=focus, dead] party1
この場合[target=]でユニットを指定しているためparty1は無視されます。このルールにはいくつかの例外があります。いくつかのコマンドにはそのコマンドに重要なkey unitがあります。もしそのユニットを[target=]の中で使用しても、コマンドのユニットを指定できます。
/focus [target=focus, dead] [target=focus, noharm] target
この場合key unitはFocusです。以下にkey unitとコマンドのデフォルトユニットの一覧を示します。
Command | Key Unit | Default Unit
------------- ----------- -------------
/target | target |
/focus | focus | target
/startattack | target | target
/petattack | pettarget | target

2.5 条件
条件のリストを示し、その意味を解説します。

2.5.1 完全版条件リスト
help - Can cast helpful spells on the target
harm - Can cast harmful spells on the target
exists - Target exists
dead - Target is dead
stance:0/1/2/.../n - In a stance
stealth - Stealthed
modifier:shift/ctrl/alt - Holding the given key
button:1/.../5/<virtual click> - Macro activated with the given mouse button
equipped:<item type> - item type is equipped (item type can be an inventory slot, item type, or item subtype)
channeling:<spell name> - Channeling the given spell
actionbar:1/.../6 - Given action bar page is selected
pet:<pet name or type> - The given pet is out
combat - In combat
mounted - Self explanatory
swimming - Self explanatory
flying - Mounted or in flight form AND in the air
flyable - In a zone where flying is allowed
indoors - Self explanatory
outdoors - Self explanatory
party - Target is in your party
raid - Target is in your raid/party
group:party/raid - You are in the given type of group

2.5.2 help & harm
回復等のhelpful spellを詠唱できる対象がhelp、攻撃等のharmful spellを詠唱できる対象がharm

2.5.3 exists
対象が生きていればtrue、対象がない場合はfalse、勿論対称が死んでいたらfalse。help/ harm/ party/ raid等の条件は生きているのが前提なので、それらがtrueであればexistsもtrueなので、existsは省略して構わない。

2.5.4 dead
対象が死んでいたらtrue。

2.5.5 stance:0/1/2/.../n
各stanceの割り当て番号一覧
Stance Warrior Druid Priest Rogue Shaman
1 Battle Stance Bear Form Shadowform Stealth Ghost Wolf
2 Defensive Stance Aquatic Form
3 Berserker Stance Cat Form
4 Travel Form
5 Moonkin Form,
Tree of Life Form
6 Flight Form

例)
/cancelform [nostance:0/1/3]
/cast [stance:1/3] Faerie Fire (Feral)(); [nostance] Faerie Fire

DruidがBearまたはCat formの時はFaerie Fire (Feral)を詠唱し、それ以外のときはformを解いて(formしてない時はそのまま)Faerie Fireを詠唱するmacroです。

2.5.6 stealth
Rogueがステルスしている時はtrue。Night ElfのShadowmeld、MageのInvisivility等も同様に扱われる。

2.5.7 modifier:shift/ctrl/alt
それぞれのキーを押した状態でmacroを実行したらtrue。
/cast [modifier, help] [modifier, target=targettarget, help] Flash Heal; [help] [target=targettarget] Greater Heal
これは任意のmodifierキーを設定し、キーを押したままmacroを実行すると、ターゲットまたはターゲットのターゲットが味方ならFlash Healを、キーを押さなければGreater Healを詠唱するmacroです。
[modifier:shift]でshiftキーに設定され、[modifier:shift/ctrl]の場合は『shiftキーまたはctrlキー』という意味になります。両方のキーを指定したい場合は、[modifier:shift, modifier:ctrl]となります。macroに『A』というキーを割り当て[modifier:shift]とした時に、『SHIFT-A』に他のショートカットを割り当てているとmacroは動作しません。

2.5.7.1 Modifierの多様性
shift, ctrl, altをmodifierキーに設定できますが、他にも使用できるパラメーターがあります。SELFCASTはInterface opitonで設定できるself-castのキーの事で、デフォルトではatlですがaddon等の影響で変わります。
/cast [modifier:SELFCAST, target=player] [target=mouseover] [] Greater Heal
これで特にmodifierキーを設定しなくてもデフォルトの設定だけでself-castされる設定になります。他に使用できるパラメーターの一覧を上げます。

AUTOLOOTTOGGLE (shift)
STICKYCAMERA (ctrl)
SPLITSTACK (shift)
PICKUPACTION (shift)
COMPAREITEMS (shift)
OPENALLBAGS (shift)
QUESTWATCHTOGGLE (shift)
※( )内がデフォルトのキー設定です。

2.5.8 button:1/2/.../5/<virtual click>
マウスのボタン指定です。
1= left, 2=right, 3=middleそしてbutton 4 button5と続きます。
#show Swift Green Mechanostrider
/userandom [nobutton2, flyable, nomounted] Ebon Gryphon; [nomounted] Black Batttlestrider, Swift Green Mechanostrider
/dismount [noflying] [button:2]

mountに乗っていない場合、flying mountを使えるところでは左クリック(右クリックを除くマウスボタンでも可)でEbon Gryphonが使用され、使えないところではBlack BattlestriderかSwift Green Mechanostriderがランダムで使用されます。右クリックは常にランダム使用となります。mountに乗っている時は左クリックは飛行中以外はmountを降り、右クリックは飛行中に関わらずmountを降ります。

2.5.9 equipped:<item type>
特定のitemを装備していたらtrue。item typeは装備slot名、itemの種類等が使えます。装備slotとItem Typeの一覧はこちら参照。
次の例は装備によってShield BashかPummelを使用するmacroです。
#show [equipped:Shields] Shield Bash; Pummel
/cast [equipped:Shields,stance1/2] Shield Bash; [equipped:Shields] Defensive Stance; [stance:3] Pummel; Berserker Stance

まず、Shieldを装備しているかどうかで表示iconが変わります。
BattleまたはDefensive stanceでShieldを装備している場合Shield Bashを実行します。Shieldを装備している場合はDefensive Stanceに変更します。Berserker stance(でShieldを持ってない場合)はPummelを実行します。どのstanceでもなくShieldもない場合はBerserker Stanceになります。

2.5.10 channeling:<spell name>
指定したspellにchanneling中であればtrue。spellの指定がない場合は何かのspellにchanneling中であればtrue。Arcane Missiles、Drain Life、Mind Flay等のchannelingするspellで有効。

2.5.11 actionbar:1/.../6
actionbarのページの指定。
/swapactionbar 1 2
/cast [actionbar:1] Aspect of the Hawk; Aspect of the Monkey

これはactionbarのページを1と2で切り替え、1ならばAspect of the Hawkを、2ならばAspect of the Monkeyを使用するmacro。

2.5.12 pet:<pet name or type>
現在のpetを名前または種類で指定する。
次のmacroはmageがelementalがいる時はpetのFreeze、いない時は自身でFrost Novaを撃つMacro。
/cast [pet] Freeze; Frost Nova

2.5.13 combat
戦闘中ならtrue。

2.5.14 mounted, swimming, flying, indoors & outdoors
それぞれ、mountに乗ってたらtrue、泳いでいたらtrue、飛行中ならtrue、屋内/ 屋外ならtrue。

2.5.15 flyable
flying mountを使用できる所ならtrue。

2.5.16 party & raid
自分のpartyまたはraidのメンバーならtrue。

2.5.17 group:party/raid
自分がpartyを組んでいるまたはraidを組んでいるならtrue。
/cast [group, nomodifier] Arcane Brilliance; [help] [target=player] Arcane Intellect
グループにいるときはArcane Brillianceを詠唱、soloの時は味方のターゲットか自分にArcane Intellectを詠唱する。

2.6 Macro Option Applications
コマンドは実際にはいくつかのoptionを合わせて使用します。次は具体的な例を上げて補足していきます。

2.6.1 Using Focus
Focusはunitの一つでターゲットを一つ記憶しておけます。最も簡単な使い方はkey bindでFocus TargetとTarget Focusを使用できます。前者は現在のターゲットをFocusに指定するもので、後者はFocusしているものをターゲットにするものです。
Focusはcrowd control(CC)で良く使われます。次に上げるのは、DPSのターゲットを変えずにfocusしているターゲットをpolymorphするマクロです。
/cast [target=focus] Polymorph
unit IDをfocusの対象に指定したmacroを作る事もできます。
/focus party3target
3番目のparty memberのターゲットをFocusにするmacroです。/clearfocusコマンドはFocusを解除します。
もっと高度なfocusの使用例を上げます。
/focus [target=focus, noharm] [target=focus, dead] [modifier]
/stompacro [target=focus, noexists]
/cast [target=focus] Polymorph

1行目で、現在のFocusが敵ではない場合やFocusが死んでいる場合、(上では設定してませんが)modifierキーを押している場合には現在のターゲットをFocusにします。
2行目で、この時点でFocusがない場合、つまりTargetが無い状態で1行目が実行された場合はmacroを止めます。
3行目で、FocusにPolymorphを実行します。

2.6.2 Macro Branching with /click
modifierキーとマウスボタンの組み合わせで違うspellを使うよう設定するmacroを上げます。
/cast [modifier:shift, button:1, target=party1] [modifier:shift, button:2, target=player] Greater Heal; [modifier:ctrl, button:1, target=party1] [modifier:ctrl, button:2, target=player] Flash Heal; [nomodifier, button:1, target=party1] [nomodifier, button:2, target=player] Renew
これは見にくいのですが、225文字の制限を越えるのを承知で複数行に分割して見やすくしてみます。
/cast [modifier:shift, button:1, target=party1] [modifier:shift, target=player] Greater Heal
/cast [modifier:ctrl, button:1, target=party1] [modifier:ctrl, target=player] Flash Heal
/cast [button:1, target=party1] [target=player] Renew

しかし、targetを指定するmaster macroをつくり、macro2をMultiBarLeftButton2にmacro3をMultiBarLeftButton3に入れておく事によりもっと簡単に記述する事ができます。
Macro1(Master Macro)
/click [button:1] MultiBarLeftButton; MultiBarLeftButton3
Macro2
/cast [modifier:shift, target=party1] Greater Heal; [modifier:ctrl, target=party1] Flash Heal; [target=party1] Renew
Macro3
/cast [modifier:shift, target=player] Greater Heal; [modifier:ctrl, target=player] Flash Heal; [target=player] Renew

3 Miscellany

3.1 Iconのカスタマイズ
自分の好きなIconを追加する事ができます。World of Warcraft\Interface\Iconsのフォルダーに画像ファイルを入れればOKです。画像ファイルには指定があり、BLPファイルか24bitか24bit alphaのTGAファイルです。最大512(例:32x32, 512x128等)

3.2 複数のコンピューターでmacroを共有する
World of Warcraft\WTF\Account\Youraccountnameのファイルをコピーします。これはaddonの設定なども含まれています。(addon自体は各PCに入れなければいけません)
もしmacroだけを共有したい場合は、World of Warcraft\WTF\Account\Youraccountname\macros-cache.txtがGeneral macroで、Warcraft\WTF\Account\Youraccountname\Yourrealmname\Yourcharactername\macros-cache.txtがcharacter-specific macroで、これらをコピーします。

3.3 More Information
もっと知りたい場合は、公式のMacro Forum等を参照してください。

3.4 Acknowledgments
感謝の言葉が述べられてますがmacro関係ないので省きます。

Page Top

Uber Link

Official Site

WoW News

Database Site

Map Site

Addon Site

File & Movie

Arena

Raid

日本語サイト